Будьте в курсе всех новостей про IP-телефонию и Asterisk.

Подписка на еженедельную рассылку компании VoxLink. Статьи и инструкции по настройке Asterisk и VoIP-оборудования, рецепты и лайфхаки, обучение и бесплатные вебинары.

Будь в теме

Курсы по использованию Asterisk

IP-телефония — технология будущего. Обучитесь работе с IP-АТС Asterisk для того чтобы внедрить и профессионально использовать при решении коммуникационных задач.

Работайте с Asterisk профессионально!

Многоуровневая защита IP-АТС Asterisk

Телефонные станции очень часто становятся объектами хакерских атак. Узнайте, каким образом необходимо строить многоуровневую защиту для Вашей IP-АТС.

Не оставьте хакерам шансов. Защитите свой Asterisk от атак.

Используйте Веб-Интерфейс для удобства настройки

Панель управление FreePBX позволяет легко и удобно управлять всей системой. Научитесь эффективно использовать FreePBX для решения своих задач.

Управление станцией и статистика в окне браузера.

Научитесь работать с Asterisk из консоли

Для понимания работы с Asterisk необходимо уметь настраивать его вручную с конфигурационными файлами и командной строкой CLI Asterisk.

Научитесь «тонкой» настройке Asterisk

Цель курсов - максимум практики.

Обучение нацелено на практическую работу с IP-оборудованием: платы потоков E1, VoIP-телефонные аппараты, голосовые шлюзы FXS и прочее.

Обучение на реальном оборудовании — залог успеха.

Автоматическая постановка паузы в очереди и автоматическое снятие паузы по таймауту

База знаний Настройка Asterisk

Asterisk может автоматически ставить паузу в очереди по неответу, но снять её потом должен оператор очереди вручную. Автоматическое снятие паузы в очереди может быть полезно

Asterisk может автоматически ставить паузу в очереди по неответу, но снять её потом должен оператор очереди вручную. Автоматическое снятие паузы в очереди может быть полезно, как минимум, в следующем сценарие:
В очереди требуется использовать стратегию leastrecent, но данная стратегия теряет эффективность, если какой-либо из операторов включает DND или просто не принимает входящие вызовы (например уходит с рабочего места), первый вызов в очереди при этом будет всегда поступать на проблемного оператора и не будет переходить на других операторов, т.е. вызов практически наверняка никто не примет. Ситуация будет гораздо хуже если более одного оператора одновременно включит DND или перестанет принимать вызовы. Решить эту проблему позволяет автоматическая постановка паузы в очереди при неответе, но тогда оператор может забыть снять паузу, к тому же, для работы с паузами требуется индикация состояния паузы на рабочем месте оператора и дополнительное обучение операторов работе с паузой в очереди. С такими проблемами можно и нужно бороться организационными мерами, но можно также обезопасить работоспособность колл-центра настройками Asterisk.

 Постановка на паузу

Собственно предлагаемое решение проблемы, которое будет описано в статье - автопауза в очереди при неответе и автоматическое снятие паузы через три минуты (время до снятия паузы можно отрегулировать). Таким образом вызов на проблемного оператора будет поступать только раз в три минуты, затем, после таймаута или отбоя из-за DND вызов поступит на следующего оператора, т.к. проблемный оператор будет на паузе. Когда проблемный оператор будет готов продолжить работу, пауза будет снята автоматически в течение трёх минут - оператору и его начальнику не нужно переживать насчёт потенциального простоя в том случае, если оператор забудет снять паузу вручную. При этом все паузы записываются в лог, начальник узнает о паузах оператора из статистики по очередям.

 

Настройки очереди

В качестве примера будет использоваться очередь call-center, настройки очереди из файла queues.conf приведены ниже:

[call-center]
strategy=leastrecent
autofill=yes
autopause=yes
autopausebusy=yes
autopauseunavail=yes
autopausedelay=0
joinempty=yes
leavewhenempty=no
timeout=8
retry=1
ringinuse=no
timeoutpriority=conf
timeoutrestart=yes
member=Local/101@queue-op/n,0,"Оператор 1",SIP/101
member=Local/102@queue-op/n,0,"Оператор 2",SIP/102
member=Local/103@queue-op/n,0,"Оператор 3",SIP/103

autopausebusy и autopauseunavail должны быть включены вместе с autopause, т.к. вызовы на телефоны с включенным режимом DND могут возвращать DIALSTATUS BUSY или CONGESTION в зависимости от модели и настроек телефона.

 

Диалплан

Для вызова очереди используется следующий диалплан:

exten => 1000,1,Answer
same  => n,Queue(call-center,t,,90)

 

Контекст для вызова операторов queue-op выглядит следующим образом:

[queue-op]
exten => _X.,1,Set(DIALSTATUS=)
same  => n,Set(QUEUE_OP=${EXTEN})
same  => n,Set(QUEUE_CONTEXT=${CONTEXT})
same  => n,Dial(SIP/${EXTEN},15,t)
 
exten => h,1,GotoIf($["${DIALSTATUS}" = "ANSWER"]?end)

same  => n,Set(DB(PAUSE_ID/${QUEUE_OP}/id)=${UNIQUEID}) same  => n,AGI(auto_unpause.pl,180,Local/${QUEUE_OP}@${QUEUE_CONTEXT}/n,${UNIQUEID})
same  => n(end),Hangup
 

Если оператор не отвечает на вызов из очереди, запускается AGI-скрипт auto_unpause.pl с тремя параметрами:
1) время в секундах, через которое пауза оператора будет снята
2) канал оператора, на котором будет снята пауза
3) идентификатор паузы (в данном случае используется UNIQUEID канала)


Идентификатор паузы записывается в AstDB, скрипт снимет паузу только в том случае, если по прошествии указанного промежутка времени, идентификатор паузы в AstDB не изменится. Идентификатор паузы нужен на тот случай, если за прошедшее время оператор успеет снять и снова установить паузу вручную или если пауза будет включена по какой-либо другой причине (в остальных местах, где устанавливается пауза, нужно также записывать UNIQUEID канала в ветку AstDB «PAUSE_ID»).

 

AGI-скрипт

Ниже приведён код AGI-скрипта auto_unpause.pl, снимающего паузу в очереди, скрипт нужно разместить в директории для AGI-скриптов (обычно /var/lib/asterisk/agi-bin).
В переменные $ami_host, $ami_port, $ami_user, $ami_pass в теле скрипта нужно внести данные для подключения к AMI. У пользователя, используемого для подключения, должны быть write-привилегии system и agent. Для работы скрипта должны быть установлены perl-модули Asterisk::AGI и IO::Socket.

 

#!/usr/bin/perl
 
use warnings;
use strict;
use utf8;
use Asterisk::AGI;
use IO::Socket;
use POSIX 'setsid';
use Cwd 'chdir';
 
#use Data::Dumper;
 
use constant AMI_CONNECT_TIMEOUT        => 3;
use constant AMI_READ_TIMEOUT           => 5;
use constant AMI_RES_VALUE              => 0;
use constant AMI_RES_ACTIONID           => 1;
use constant AMI_RES_DATA               => 2;
 
my $agi = new Asterisk::AGI;
my $use_agi = 1;
 
my $unpause_time = $ARGV[0];
my $op_interface = $ARGV[1];
my $pause_id = $ARGV[2];
 
if(not defined $unpause_time or not $unpause_time =~ /^[0-9]+$/ or not defined $op_interface or $op_interface eq '') {
        die 'Bad parameters';
}
 
my $ami_host = 'localhost';
my $ami_port = 5038;
my $ami_user = 'admin';
my $ami_pass = 'secret';
 
daemonize(*STDERR, *STDOUT, *STDIN);
open STDIN, '</dev/null' or exit;
open STDOUT, '>/dev/null' or exit;
open STDERR, '>/dev/null' or exit;
 
sleep $unpause_time;
 
my $ami_sock = ami_connect($ami_host,$ami_port,$ami_user,$ami_pass);
unless($ami_sock) {
        die 'failed to connect to AMI'; }
 
if(defined $pause_id and $pause_id ne '') {
        if($op_interface =~ /^Local\/([^@]+)/) {
                my $op_exten = $1;
                my $pause_id_match = 0;
                my $resp = ami_dbget($ami_sock,'PAUSE_ID/'.$op_exten,'id');
                if(defined $resp->[2] and ref($resp->[2]) eq 'ARRAY' and defined $resp->[2]->[0]) {
                        if($resp->[2]->[0] eq $pause_id) {
                                $pause_id_match = 1;
                        }
                }
                unless($pause_id_match) {
                        close($ami_sock);
                        die "pause_id doesn't match";
                }
        }
}
 
my $pause = '';
ami_queue_pause($ami_sock,$op_interface,$pause,'','Clerical-Pause');
 
close($ami_sock);
 
###
### SCRIPT END
###
 
sub ami_connect {
        my ($ami_host, $ami_port, $ami_user, $ami_pass) = @_;
        my $sock = 0;
        
        $sock = IO::Socket::INET->new(
                Proto           => "tcp",
                PeerAddr        => $ami_host,
                PeerPort        => $ami_port,
                Timeout         => AMI_CONNECT_TIMEOUT
        );
        $sock or return 0;
        $sock->autoflush(1);
        
        my $action_id = gen_pass(10);
        my $login_msg = "Action: Login\r\nActionID: $action_id\r\nUsername: $ami_user\r\nSecret: $ami_pass\r\nEvents: off\r\n\r\n";
        print $sock "$login_msg";
        
        my $response = ["",""];
        
        while($response->[AMI_RES_ACTIONID] ne $action_id) {
                $response = read_ami_message($sock,'Login',AMI_READ_TIMEOUT);
                if($response->[AMI_RES_VALUE] eq "Error") {
                        syslog('err',"Authentication failed");
                        close $sock;
                        return 0;
                } elsif($response->[AMI_RES_VALUE] eq "") {
                        #syslog('err',"AMI read timed out");
                        close $sock;
                        return 0;
                }
        }
        
        return $sock;
}
 
sub read_ami_message {
        my ($sock,$action,$read_timeout,$nolog) = @_;
        if(not defined $action) { $action = 'Unspecified'; }
        if(not defined $read_timeout) { $read_timeout = AMI_READ_TIMEOUT; }
        my @result = ("", "", {});
        
        eval {
                my $sig_alrm_orig = $SIG{ALRM};
                local $SIG{ALRM} = sub { goto end_eval };
                alarm $read_timeout;
                
                my $response_text = 0;
                my $ami_line = '';
                my $keep_going = 1;
                my $first_run = 1;
                while($keep_going) {
                        if($first_run) {
                                $first_run = 0;
                                while($ami_line eq '') { $ami_line = <$sock>; $ami_line =~ s/\r\n//g; }
                        } else { $ami_line = <$sock>; $ami_line =~ s/\r\n//g; }
                        # Read failed
                        if(not defined $ami_line) { last; }
                        #print "$ami_line\n";
                        if($response_text and $action eq 'Command') {
                                if($ami_line eq '--END COMMAND--') { $keep_going = 0; }
                                else { push(@{$result[AMI_RES_DATA]->{'Response'}},$ami_line); }
                        } else {
                                if($ami_line eq '') { $keep_going = 0; }
                                if($ami_line =~ /^([^:]+): (.*)$/) {
                                        if($1 eq "Event" or $1 eq "Response") { $result[AMI_RES_VALUE] = $2 }
                                                elsif($1 eq "ActionID") { $result[AMI_RES_ACTIONID] = $2 }
                                        else { $result[AMI_RES_DATA]->{$1} = $2 }
                                } elsif($action eq 'Command') {
                                        $response_text = 1;
                                        if($ami_line eq '--END COMMAND--') { $keep_going = 0; }
                                        else { $result[AMI_RES_DATA]->{'Response'} = [ $ami_line ]; }
                                }
                        }
                }
                
                alarm 0;
                end_eval:
                $SIG{ALRM} = $sig_alrm_orig;
        };
        
        #print "message read\n";
        if($result[AMI_RES_VALUE] eq '') {
                print STDERR "AMI read timed out while doing '$action'\n" unless defined $nolog;
        }
        
        return \@result;
}
 
sub ami_dbget {
        my $sock = ${shift(@_)};
        my ($family, $key) = @_;
        
        my $action_id = gen_pass(10);
        my $msg = "Action: DBGet\r\nActionID: $action_id\r\nFamily: $family\r\nKey: $key\r\n\r\n";
        
        print $sock "$msg";
        
        my $response = ['', ''];
        
        while($response->[AMI_RES_ACTIONID] ne $action_id) {
                $response = read_ami_message($sock,'DBGet',AMI_READ_TIMEOUT);
                if($response->[AMI_RES_VALUE] eq "") {
                        print STDERR "ERROR    AMI DBGet read timed out\n$msg";
                        return $response;
                } elsif($response->[AMI_RES_VALUE] eq "Success") {
                        $response->[AMI_RES_DATA] = [];
                        my $res1 = ['dummy', ''];
                        while($res1->[AMI_RES_VALUE] ne '') {
                                $res1 = read_ami_message($sock,'DBGetResponse',2);
                                if($res1->[AMI_RES_ACTIONID] eq $action_id) {
                                        if($res1->[AMI_RES_VALUE] eq 'DBGetResponse') {
                                                if(defined $res1->[AMI_RES_DATA]->{'Val'}) {
                                                        push(@{$response->[AMI_RES_DATA]},$res1->[AMI_RES_DATA]->{'Val'});
                                                } else {
                                                        print STDERR "ERROR    'Val' not defined in DBGetResponse\n";
                                                }
                                        } elsif($res1->[AMI_RES_VALUE] eq 'DBGetComplete') {
                                                last;
                                        } elsif($res1->[AMI_RES_VALUE] eq '') {
                                                print STDERR "ERROR    AMI DBGetResponse read timed out\n";
                                                last;
                                        } else {
                                                print STDERR "ERROR    AMI DBGetResponse read returned unexpected response $res1->[AMI_RES_VALUE]\n";
                                                last;
                                        }
                                }
                        }
                } else {
                        print STDERR "ERROR    AMI action failed\n$msg";
                }
        }
        
        return $response;
}
 
sub ami_queue_pause {
        my ($sock, $interface, $pause, $queue, $reason) = @_;
        
        my $response = ['', ''];
        
        if(not defined $interface or $interface eq '') {
                print STDERR "ERROR     Bad interface in ami_queue_pause: $interface\n";
                return $response;
        }
        
        my $action_id = gen_pass(10);
        my $pause_act = 'true';
        if(not defined $pause or $pause eq '' or $pause eq 'false' or $pause eq '0') { $pause_act = 'false'; }
        my $msg = "Action: QueuePause\r\nActionID: $action_id\r\nInterface: $interface\r\nPaused: $pause_act\r\n";
        if(defined $queue and $queue ne '') {
                $msg .= "Queue: $queue\r\n";
        }
        if(defined $reason and $reason ne '') {
                $msg .= "Reason: $reason\r\n";
        }
        $msg .= "\r\n";
        
        print $sock "$msg";
        
        while($response->[AMI_RES_ACTIONID] ne $action_id) {
                $response = read_ami_message($sock,'QueuePause',AMI_READ_TIMEOUT);
                if($response->[AMI_RES_VALUE] eq "") {
                        print STDERR "ERROR    AMI Command read timed out\n$msg";
                        last;
                } elsif($response->[AMI_RES_ACTIONID] eq $action_id and $response->[AMI_RES_VALUE] ne "Success") {
                        #print $response->[AMI_RES_VALUE]."\n";
                        #print STDERR "ERROR    AMI action failed\n$msg";
                        last;
                }
        }
        
        return $response;
}
 
sub gen_pass {
        my $pass_len = shift(@_);
        my $var = shift(@_);
        my $num_only = shift(@_);
        
        my @chars = ('a'..'z','A'..'Z','0'..'9','_','-');
        if($var) { $pass_len = int(rand 4) + $pass_len - 2 }
        if($num_only) { @chars = ('0'..'9') }
        my $pass = "";
        foreach (1..$pass_len) { $pass .= $chars[rand @chars]; }
        return $pass;
}
 
sub daemonize {
        # Fork, start new session and fork again
        my $pid = fork;
        exit 0 if $pid;
        exit 1 if not defined $pid;
 
        setsid();
        $pid = fork;
        exit 0 if $pid;
        exit 1 if not defined $pid;
 
        # Chdir to /
        chdir '/' or die $!;
        umask 0;
 
        # Close all provided filehandles
        close $_ for @_;
}

 

asterisk, sip, Event, Time, for, call